Hier ein Apple-Script, dass als Folder-Action an einen Ordner angefügt werden kann.

Wenn eine Datei oder ein Ordner in den Ordner gelegt wird, werden automatisch die Zugriffsrechte für allen Unterobjekten auf Lese- und Schreibzugriff für alle Benutzer geändert (chmod 777), zusätzlich wird an jeden Unterordner das Skript als Folder-Action angefügt.

Das Skript kann zum Beispiel dazu genutzt werden auf einem File-Server alle Objekte in einer Freigabe für alle Benutzer les- und schreibbar zu halten, auch wenn ein Benutzer ausversehen ein Objekt mit "falschen" Zugriffsrechten in den Ordner kopiert.

on adding folder items to this_folder after receiving added_items
    tell application "Finder"
        repeat with this_item in added_items
            my theScript(this_item)
            my subfolders(this_item)
        end repeat
    end tell
end adding folder items to
 
on subfolders(this_folder)
    tell application "Finder"
        repeat with each_folder in (get every folder of this_folder)
            my theScript(each_folder)
            my subfolders(each_folder)
        end repeat
    end tell
end subfolders
 
on theScript(action_folder)
    set script_file to ((path to library folder as Unicode text) & "Scripts:Folder Action Scripts:chmodPublic_and_addScript.scpt" as Unicode text)
    tell application "System Events"
        attach action to (action_folder as alias) using (script_file as alias)
    end tell
 
    set posix_path to quoted form of POSIX path of action_folder as string
    set ScriptReturn to do shell script "/bin/chmod -R -f 777 " & posix_path
 
end theScript